adox,ms访问和asp

您的计算机上不需要安装MS访问,为ASP网站创建数据库文件。使用adox和某些数据定义语言允许您以编程方式生成MDB文件。

ADO(ActiveX数据对象)主要由ASP程序员用于操纵数据 - 即从数据存储中检索到网页上的数据存储,并允许用户在数据存储中插入或修改数据。

ADO还可以用作传递DDL(数据隐隐语言)命令的方法来在数据库中创建,删除和更改表及其字段,但是创建新的访问数据库或基于其他基于模式的活动呢?

adox(ADO扩展)是这个工具。 adox对象模型从目录对象开始,它是顶级对象。目录对象包含许多对象作为属性,每个对象是集合。 (例如,目录对象的Tables属性是表对象的集合。)这些目录对象属性包括:

  • 桌子
  • 团体
  • 用户
  • 程序
  • 意见

目录对象表示数据存储的顶级对象,架构信息。以下是如何使用它来创建新的访问.mdb文件并将表添加一个主键。

 
<%
  'Const adVarWChar = 202
  'Const adInteger = 3
  'The above are from adovbs.inc and are the ADO Constants 
  'for the two datatypes used in this example.
  
  Dim objADOXDatabase
  'Instantiate a Catalog object
  Set objADOXDatabase = CreateObject("ADOX.Catalog")
  
  'Use the Create method, passing the Datasource Provider 
  'and full path and file name as parameters
  objADOXDatabase.Create "Provider=Microsoft.Jet.OLEDB.4.0;" & _
  "Data Source=PathToDatabasecustomers.mdb"
  'The database now exists...
  
  'Create a database table and name it
  Dim objFirstTable 
  Set objFirstTable = CreateObject("ADOX.Table")
  objFirstTable.Name = "Customers"
  
  'CustomerID will be of datatype adInteger, for which the ADO Constant is 3
  objFirstTable.Columns.Append "CustomerID", 3
  
  'CustomerName is of datatype adVarWChar, for which the ADO Constant is 202. 
  'The field size is 30 characters
  objFirstTable.Columns.Append "CustomerName", 202, 30
  
  'Create a key, passing first the name of the key, 
  'then the type (1 = primary key), 
  'then the column on which it is created
  objFirstTable.Keys.Append "PK_CustomerID", 1, "CustomerID"
  
  'Add the database table to the database 
  objADOXDatabase.Tables.Append objFirstTable
  response.write "Database created"
  'Clean up...
  Set objFirstTable = Nothing
  Set objADOXDatabase = Nothing
  %>